blob: fff45e6ed2ce3ac611d0caa3551f25ad018b4c4e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Caltlgin Stsodaat <contact@fossdaily.xyz>
pkgname=nuclei
pkgver=2.1.0
pkgrel=1
pkgdesc='Fast tool for configurable targeted scanning based on templates offering massive extensibility and ease of use'
arch=('x86_64')
url='https://github.com/projectdiscovery/nuclei'
license=('MIT')
makedepends=('go')
provides=("${pkgname}")
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
sha256sums=('744bb5a04e79e74970fe163183d673be58c0a3a3db6a9481cafbaaaa93bbebeb')
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
export GOPATH="${srcdir}"
cd "${pkgname}-${pkgver}/v2"
go build -v -o "${pkgname}" ."/cmd/${pkgname}"
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm755 -t "${pkgdir}/usr/bin" "v2/${pkgname}"
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" 'README.md'
install -Dm644 'LICENSE.md' "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim: ts=2 sw=2 et:
|