blob: d5c419e5581a0f101d0ca086630fc6db8954ea97 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
pkgname=numix-circle-icon-theme-git
pkgver=0.r1677.fe74d83
pkgrel=1
pkgdesc='Circle icon theme from the Numix project'
arch=('any')
url='http://numixproject.org/'
license=('GPL3')
depends=('numix-icon-theme-git')
makedepends=('git')
provides=('numix-circle-icon-theme' 'numix-circle-light-icon-theme')
conflicts=('numix-circle-icon-theme' 'numix-circle-light-icon-theme')
options=('!strip')
install='numix-circle-icon-theme.install'
source=('numix-circle-icon-theme::git+https://github.com/numixproject/numix-icon-theme-circle.git')
sha256sums=('SKIP')
pkgver() {
cd numix-circle-icon-theme
printf "0.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
package() {
cd numix-circle-icon-theme
install -dm 755 "${pkgdir}"/usr/share/icons
cp -dr --no-preserve='ownership' Numix-Circle{,-Light} "${pkgdir}"/usr/share/icons/
}
# vim: ts=2 sw=2 et:
|