blob: 0af9c821150dbc86eff24355f8e7cba01b9e5ba6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Marcin Tydelski <marcin.tydelski@gmail.com>
# Contributor: Siddhartha Das bablu.boy@gmail.com>
pkgname=nutty-git
_app_id=com.github.babluboy.nutty
pkgver=1.1.1.r75.g8838eeb
pkgrel=2
pkgdesc='A network utility that monitors the devices on your network,
checks bandwidth and speed details.'
arch=('x86_64')
url='https://github.com/babluboy/nutty'
license=('GPL3')
depends=('granite' 'iproute2' 'libgee' 'libnotify' 'libxml2' 'net-tools' 'nethogs'
'nmap' 'pciutils' 'speedtest-cli' 'sqlite' 'traceroute' 'vnstat' 'wireless_tools')
makedepends=('git' 'meson' 'vala')
checkdepends=('appstream-glib')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
install="${pkgname%-git}.install"
source=('git+https://github.com/babluboy/nutty.git')
md5sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
arch-meson "${pkgname%-git}" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
ln -s "/usr/bin/$_app_id" "$pkgdir/usr/bin/${pkgname%-git}"
# Included speedtest-cli script is broken, use system package:
rm "$pkgdir/usr/share/$_app_id/scripts/speedtest-cli"
ln -s /usr/bin/speedtest-cli "$pkgdir/usr/share/$_app_id/scripts/"
}
|