blob: 593638f14ecf0b026b658cb3adad4691eb89a086 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: "Jayesh Badwaik" jayesh@badwaik.dev
pkgname=nvhpc
_REL_YEAR=2022
_CUDA_VER=11.7
pkgver=22.7
pkgrel=3
pkgdesc='NVIDIA HPC SDK'
arch=('x86_64')
url="https://developer.nvidia.com/hpc-sdk"
license=('custom')
depends=('numactl' 'java-runtime')
optdepends=('env-modules')
makedepends=('bash')
replaces=('pgi-compilers')
conflicts=('pgi-compilers')
_pkgname="nvhpc_${_REL_YEAR}_${pkgver//.}_Linux_${arch}_cuda_${_CUDA_VER}"
source=("https://developer.download.nvidia.com/hpc-sdk/$pkgver/$_pkgname.tar.gz"
"nvhpc.sh")
sha256sums=('d536b937d1b2b3cdb74f7fb63dad3df7918b94338f0c2602b8f3f06fc7fb9655'
'316a02bebc92b86e449486280117f624c11a325d92a0d041ac3fb69931f75b2e')
options=(!strip)
prepare() {
cd "$srcdir/$_pkgname"
sed -i "s/en_US\.UTF\-8/C/g" "install_components/Linux_x86_64/$pkgver/compilers/bin/makelocalrc"
}
package() {
cd "$srcdir/$_pkgname"
NVHPC_SILENT=true \
NVHPC_INSTALL_DIR="$pkgdir/opt/nvidia/hpc_sdk" \
bash ./install
# Remove references to $pkgdir from module files
cd "$pkgdir/opt/nvidia/hpc_sdk/modulefiles"
find . -type f -exec sed -i "s@$pkgdir@@g" {} \;
# Install license
cd "$srcdir/$_pkgname/install_components/Linux_$arch/$pkgver/compilers/license"
install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
# Install script to set path
install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/etc/profile.d/$pkgname.sh"
}
|