blob: 17135f83623091a75233e5a5cc09721f7f836d09 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer : Daniel Bermond <dbermond@archlinux.org>
# Contributor: Det <nimetonmaili g-mail>
# Contributor: Ng Oon-Ee
# Contributor: Dan Vratil
pkgname=nvidia-beta
pkgver=615.78.08
pkgrel=1
pkgdesc="NVIDIA kernel module (beta version)"
arch=('x86_64')
url='https://www.nvidia.com/'
license=('LicenseRef-Custom')
makedepends=(
'dkms'
'linux-headers')
provides=("nvidia=${pkgver}" "nvidia-beta=${pkgver}" 'NVIDIA-MODULE')
conflicts=('nvidia')
options=('!strip')
_pkg="NVIDIA-Linux-${CARCH}-${pkgver}-no-compat32"
source=("http://us.download.nvidia.com/XFree86/Linux-${CARCH}/${pkgver}/${_pkg}.run"
'110-nvidia-change-dkms-conf.patch')
sha256sums=('e9d5167f4ca67f58b2b3447584b1e4273218d5088aba210d3aef2a407e522892'
'673dc16f8b2e962c8f2081fa57b4a4b2774f783205e6eb20120f3d0d1a42317e')
prepare() {
# extract the source file
[ -d "$_pkg" ] && rm -rf "$_pkg"
printf '%s\n' " -> Self-Extracting ${_pkg}.run..."
sh "${_pkg}.run" --extract-only
ln -s kernel "${_pkg}/nvidia-${pkgver}"
patch -d "$_pkg" -Np1 -i "${srcdir}/110-nvidia-change-dkms-conf.patch"
}
build() {
fakeroot dkms build --dkmstree "$srcdir" --sourcetree "${srcdir}/${_pkg}" -m "nvidia/${pkgver}" -k "$(</usr/src/linux/version)"
}
package() {
depends=(
'libglvnd'
'linux'
"nvidia-utils-beta=${pkgver}")
local _kernver
_kernver="$(</usr/src/linux/version)"
install -D -m644 "nvidia/${pkgver}/${_kernver}/${CARCH}/module"/* -t "${pkgdir}/usr/lib/modules/${_kernver}/extramodules"
install -D -m644 "${_pkg}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
find "$pkgdir" -name '*.ko' -exec zstd --rm -19 {} +
}
|