blob: 4c03c1673a09b92ae47c22935556af7e0dfb422d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer : Daniel Bermond < gmail-com: danielbermond >
# Contributor: Det <nimetonmaili g-mail>
# Contributor: Ng Oon-Ee
# Contributor: Dan Vratil
# Based on [extra]'s nvidia: https://www.archlinux.org/packages/extra/x86_64/nvidia/
pkgname=nvidia-beta
pkgver=415.13
pkgrel=1
pkgdesc="NVIDIA drivers for Arch's official 'linux' package (beta version)"
arch=('x86_64')
url='https://www.nvidia.com/'
license=('custom:NVIDIA')
depends=('linux' "nvidia-utils-beta>=${pkgver}" 'libgl')
makedepends=('linux-headers')
provides=("nvidia=${pkgver}")
conflicts=('nvidia')
options=('!strip')
_pkg="NVIDIA-Linux-${CARCH}-${pkgver}-no-compat32"
source=("https://us.download.nvidia.com/XFree86/Linux-${CARCH}/${pkgver}/${_pkg}.run"
'linux-4.16.patch')
sha256sums=('77f06aefe03d74334da642a452a2986f6da02dbc6c5a8433635178be9dfae07d'
'622ac792ec200b2239cb663c0010392118b78c9904973d82cd261165c16d6385')
_extramodules=extramodules-ARCH
prepare() {
# extract the source file
[ -d "$_pkg" ] && rm -rf "$_pkg"
printf '%s\n' " -> Self-Extracting ${_pkg}.run..."
sh "${_pkg}.run" --extract-only
# restore phys_to_dma support
# https://bugs.archlinux.org/task/58074
cd "$_pkg"
patch -Np1 -i "${srcdir}/linux-4.16.patch"
}
build() {
cd "${_pkg}/kernel"
local _kernel
_kernel="$(cat "/usr/lib/modules/${_extramodules}/version")"
printf '%s\n' " -> Building Nvidia module for ${_kernel}..."
make SYSSRC="/usr/lib/modules/${_kernel}/build" module
}
package() {
install -D -m644 "${_pkg}/kernel/"nvidia{,-drm,-modeset,-uvm}.ko -t "${pkgdir}/usr/lib/modules/${_extramodules}"
gzip -n "${pkgdir}/usr/lib/modules/${_extramodules}/"*.ko
printf '%s\n' 'blacklist nouveau' | install -D -m644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/nvidia.conf"
install -D -m644 "${_pkg}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|