blob: 5be58b822c07911511f5d1f818b0395e0d782e1b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Kien Dang <mail at kien dot ai>
# Maintainer: Julie Shapiro <jshapiro at nvidia dot com>
pkgname=nvidia-container-toolkit
pkgver=1.10.0
pkgrel=1
pkgdesc='NVIDIA container runtime toolkit'
arch=('x86_64')
url='https://github.com/NVIDIA/nvidia-container-toolkit'
license=('Apache')
makedepends=('go')
depends=('libnvidia-container-tools>=1.9.0')
conflicts=('nvidia-container-runtime-hook' 'nvidia-container-runtime<2.0.0')
replaces=('nvidia-container-runtime-hook')
options=(!lto)
backup=('etc/nvidia-container-runtime/config.toml')
source=("v${pkgver}-${pkgrel}.tar.gz"::"${url}/archive/v${pkgver}.tar.gz")
sha256sums=('7c88e6b16df92feac9a14f7ca7f2960409c71760b2563fea29c57c8799930db3')
install=$pkgname.install
_srcdir="nvidia-container-toolkit-${pkgver}"
build() {
cd "${_srcdir}"
mkdir bin
GO111MODULE=auto \
GOPATH="${srcdir}/gopath" \
go build -v \
-modcacherw \
-buildmode=pie \
-gcflags "all=-trimpath=${PWD}" \
-asmflags "all=-trimpath=${PWD}" \
-ldflags "-s -w -extldflags ${LDFLAGS}" \
-o bin \
"./..."
# -trimpath \ # only go > 1.13
#-ldflags " -s -w -extldflags=-Wl,-z,now,-z,relro" \
# go leaves a bunch of local stuff with 0400, making it break future `makepkg -C` _grumble grumble_
GO111MODULE=auto \
GOPATH="${srcdir}/gopath" \
go clean -modcache
}
package() {
install -D -m755 "${_srcdir}/bin/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
pushd "${pkgdir}/usr/bin/"
ln -sf "${pkgname}" "nvidia-container-runtime-hook"
popd
install -D -m644 "${_srcdir}/config/config.toml.centos" "${pkgdir}/etc/nvidia-container-runtime/config.toml"
install -D -m644 "${_srcdir}/oci-nvidia-hook.json" "${pkgdir}/usr/share/containers/oci/hooks.d/00-oci-nvidia-hook.json"
install -D -m644 "${_srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}
|