PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: kang <kang at insecure dot ws>
# Contributor: Original PKGBUILD from nomad-firewall-git maz-1 <ohmygod19993 at gmail dot com>

_pkgname=nx-firewall
pkgname=nx-firewall-git
pkgver=0.1.r73.g1da8c2e
pkgrel=1
pkgdesc="kcm module for firewall from nx desktop"
arch=('i686' 'x86_64')
url="https://github.com/nx-desktop/nx-firewall"
license=('GPL3')
depends=('kdeclarative' 'kcoreaddons' 'kcmutils' 'ki18n' 'plasma-framework' 'kdelibs4support'
        'kauth' 'kconfig' 'kio' 'knewstuff' 'kconfigwidgets' 'net-tools' 'ufw' 'kdesignerplugin')
makedepends=('git' 'extra-cmake-modules' 'kdoctools')
replaces=('nomad-firewall-git')
source=('git+https://github.com/nx-desktop/nx-firewall.git')
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  mkdir -p "$srcdir/build"
  cd "$srcdir/build"

# Release uses -Werror and the git code isn't all that clean, use that when they are actual releases
#    -DCMAKE_BUILD_TYPE=Release \
  cmake "$srcdir/$_pkgname" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DKDE_INSTALL_LIBEXECDIR=lib \
    -DKDE_INSTALL_SYSCONFDIR=/etc \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd "$srcdir/build"
  make DESTDIR="$pkgdir/" install
  ln -s kcms/org.nxos.firewall.so "$pkgdir/usr/lib/qt/plugins/org.nxos.firewall.so"
}