PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: NexAdn <nexadn@yandex.com>
_pkgname=obs-linuxbrowser
pkgname=${_pkgname}-git
pkgver=0.6.1.r3.gb618678
pkgrel=1
pkgdesc="Browser source plugin for obs-studio based on CEF. Alternative to obs-qtwebkit."
arch=("i686" "x86_64")
url="https://github.com/bazukas/obs-linuxbrowser"
license=("GPL")
conflicts=("${_pkgname}" "obs-linuxbrowser-bin")
depends=(
	"obs-studio>=21.1.2"
	"gconf" "nss" "libxss" "pango" "atk" "libxrandr" "libxcomposite"
)
makedepends=("make" "cmake" "git" "cef-minimal<75")
optdepends=("pepper-flash: Flash support"
	"cef-minimal: Up-to-date browser backend")
source=(
	"${_pkgname}::git+https://github.com/bazukas/${_pkgname}.git"
)
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}"/${_pkgname}
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd "${srcdir}"/${_pkgname}
	mkdir -p ./build
	cd ./build
	cmake -DCEF_ROOT_DIR="/opt/cef" -DINSTALL_SYSTEMWIDE=true -DCMAKE_INSTALL_PREFIX="/usr" ..
	make
}

package() {
	cd "${srcdir}"/${_pkgname}/build
	make DESTDIR="${pkgdir}" install
}