blob: 57c6c08cffdab7cbf9a2b1851bc130848fe6d5af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: tytan652 <tytan652@tytanium.xyz>
pkgname=obs-move-transition
pkgver=2.3.2
_obsver=26.1.2
pkgrel=1
pkgdesc="Plugin for OBS Studio to move sources to a new position during scene transition"
arch=('x86_64')
url="https://github.com/exeldro/obs-move-transition"
license=("GPL2")
depends=("obs-studio")
# Need to compile plugin in OBS compilation process
makedepends=(
'cmake' 'libfdk-aac' 'libxcomposite' 'x264' 'vlc' 'swig' 'python'
'luajit' 'ffmpeg' 'jansson' 'libxinerama' 'libxkbcommon-x11' 'mbedtls'
'qt5-svg' 'qt5-x11extras' 'curl' 'jack' 'gtk-update-icon-cache'
)
source=(
"$pkgname-$pkgver::git+https://github.com/exeldro/obs-move-transition#commit=e5197ec599395c656b11a6564679f442c77388de"
"obs-studio-$_obsver.tar.gz::https://github.com/obsproject/obs-studio/archive/$_obsver.tar.gz"
"fix_python_binary_loading.patch"
)
sha256sums=(
'SKIP'
'bc8b4c61ba4aae87b70c589a6a5b8538e4f03121b31e9b98a2071d9f6006b897'
'bdfbd062f080bc925588aec1989bb1df34bf779cc2fc08ac27236679cf612abd'
)
prepare() {
rm -rf fakeroot
cd "obs-studio-$_obsver"
patch -Np1 < "$srcdir"/fix_python_binary_loading.patch
cd plugins
cp -r "$srcdir/$pkgname-$pkgver" .
echo "add_subdirectory($pkgname-$pkgver)" | tee -a CMakeLists.txt >/dev/null
}
# Need to compile plugin in OBS compilation process
build() {
cd "obs-studio-$_obsver"
cmake -B build \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DBUILD_CAPTIONS=ON
make -C build
}
package() {
mkdir -p "$pkgdir"/usr/lib/obs-plugins
mkdir -p "$pkgdir"/usr/share/obs/obs-plugins
cd "obs-studio-$_obsver"
make -C build DESTDIR="$srcdir/fakeroot/" install
cp -a "$srcdir"/fakeroot/usr/lib/obs-plugins/move-transition.so "$pkgdir"/usr/lib/obs-plugins/
cp -a "$srcdir"/fakeroot/usr/share/obs/obs-plugins/move-transition "$pkgdir"/usr/share/obs/obs-plugins/
}
|