blob: 840404d9b6f92f7ee452c8c3edac54a93a175107 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
pkgname=ocserv
pkgver=0.10.6
pkgrel=1
pkgdesc="OpenConnect VPN Server"
arch=('i686' 'x86_64')
url="http://www.infradead.org/ocserv/"
license=('GPL2')
depends=('autogen' 'libpcl' 'gnutls' 'http-parser' 'libnl' 'libsystemd' 'pam' 'protobuf-c' 'talloc' 'libseccomp' 'freeradius-client')
makedepends=('freeradius')
backup=('etc/ocserv.config' 'etc/ocserv-passwd')
source=("ftp://ftp.infradead.org/pub/ocserv/ocserv-$pkgver.tar.xz")
sha256sums=('86e45d0bbaad5bf94f0b233054729004caa76024dfd058d1848c639ee8560c32')
prepare() {
cd ${pkgname}-${pkgver}
autoreconf -fi
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr --sbindir=/usr/bin
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="$pkgdir" install
install -Dm0644 doc/sample.config "$pkgdir/etc/ocserv.config"
install -Dm0600 doc/sample.passwd "$pkgdir/etc/ocserv-passwd"
install -Dm0644 doc/systemd/standalone/ocserv.service "$pkgdir/usr/lib/systemd/system/ocserv.service"
}
|