PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Maintainer: Pi-Yueh Chuang <pychuang@pm.me>
pkgname=offlineimap3-git
pkgver=r2732.721d579
pkgrel=2
pkgdesc="Read/sync your IMAP mailboxes (python3)"
arch=("any")
url="https://github.com/OfflineIMAP/offlineimap3"
license=("GPL2")
depends=(
    "python-imaplib2-git"
    "python-rfc6555"
    "python-distro"
)
makedepends=("asciidoc")
optdepends=(
    "python-gssapi: for Kerberos authentication"
    "python-portalocker: if you need to run offlineimap in Cygwin for Windows"
)
provides=("offlineimap")
conflicts=("offlineimap" "offlineimap-git")
source=(
    "${pkgname}::git+https://github.com/OfflineIMAP/offlineimap3.git"
    "imaplib2_version.patch"
)
md5sums=(
    "SKIP"
    "0ad5ba88285b4604fc6e77472892fe23"
)

pkgver() {
    cd "${srcdir}/${pkgname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "${srcdir}/${pkgname}"

    # apply patches
    patch -p1 -i "${srcdir}/imaplib2_version.patch"
}

build() {
    cd "${srcdir}/${pkgname}"
    make clean
    python setup.py build

    cd "${srcdir}/${pkgname}/docs"
    make man
}

package() {
    cd "${srcdir}/${pkgname}"
    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build

    # install README
    install -Dm644 "README.md" -t "${pkgdir}/usr/share/doc/${pkgname}"

    # install documentation
    install -Dm644 "docs/offlineimap.1" "${pkgdir}/usr/share/man/man1/offlineimap.1"
    install -Dm644 "docs/offlineimapui.7" "${pkgdir}/usr/share/man/man7/offlineimapui.7"
    install -Dm644 "offlineimap.conf" "${pkgdir}/usr/share/offlineimap/offlineimap.conf"
    install -Dm644 "offlineimap.conf.minimal" "${pkgdir}/usr/share/offlineimap/offlineimap.conf.minimal"

    #systemd files
    install -Dm644 "contrib/systemd/offlineimap.service" "${pkgdir}/usr/lib/systemd/user/offlineimap.service"
    install -Dm644 "contrib/systemd/offlineimap@.service" "${pkgdir}/usr/lib/systemd/user/offlineimap@.service"
    install -Dm644 "contrib/systemd/offlineimap-oneshot.service" "${pkgdir}/usr/lib/systemd/user/offlineimap-oneshot.service"
    install -Dm644 "contrib/systemd/offlineimap-oneshot.timer" "${pkgdir}/usr/lib/systemd/user/offlineimap-oneshot.timer"
    install -Dm644 "contrib/systemd/offlineimap-oneshot@.service" "${pkgdir}/usr/lib/systemd/user/offlineimap-oneshot@.service"
    install -Dm644 "contrib/systemd/offlineimap-oneshot@.timer" "${pkgdir}/usr/lib/systemd/user/offlineimap-oneshot@.timer"
}