PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

# Contributor: Matthias Blankertz <matthias at blankertz dot org>
# Contributor: Navkamal Rakra <navkamal90[at]gmail[dot]com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: yochananmarqos <mark.wagie@proton.me>
# Maintainer: RAMChYLD <ramchyld@gmail.com>

pkgname=('ogdf' 'ogdf-docs')
pkgtreename=foxglove
pkgver=202510
pkgrel=3
pkgdesc="The Open Graph Drawing Framework/Open Graph algorithms and Data structure Framework."
arch=('i686' 'x86_64')
url="https://ogdf.uos.de/"
license=('LicenseRef-custom AND GPL-2.0-or-later AND GPL-3.0-or-later')
makedepends=('cmake' 'doxygen' 'graphviz' 'bash')
source=('https://github.com/ogdf/ogdf/archive/refs/tags/'${pkgtreename}-${pkgver}'.tar.gz')
sha256sums=('e0496c2ac53f5bef3639ebac0f6110323bdd938b7d29ea5da79aced4a28f99b5')
# options=('staticlibs')

# Updated build and package methods contributed by yochananmarqos

build() {
	cd "$srcdir"
	cmake -B build -S "$pkgbase-${pkgtreename}-$pkgver" \
	  -DCMAKE_BUILD_TYPE='None' \
	  -DCMAKE_INSTALL_PREFIX='/usr' \
          -DBUILD_SHARED_LIBS='ON' \
	  -Wno-dev
	cmake --build build
	
	#docs 
	cd "$pkgbase-${pkgtreename}-$pkgver"
	sh "doc/build-$pkgbase-docs.sh"
}

_pick() {
	local p="$1" f d; shift
	for f; do
		d="$srcdir/$p/${f#$pkgdir/}"
		mkdir -p "$(dirname "$d")"
		mv "$f" "$d"
		rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
	done
}

package_ogdf() {
	conflicts=('coin-or-clp' 'coin-or-osi' 'coin-or-coinutils')

	DESTDIR="$pkgdir" cmake --install build

	_pick docs "$pkgdir/usr/share/doc/lib${pkgbase}"

	cd "$pkgbase-${pkgtreename}-$pkgver"
	install -Dm644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgbase/"
}

package_ogdf-docs() {
	pkgdesc+=" (documentation)"
	depends=()

	mv docs/* "$pkgdir"
}

# check() {
# 	cd "$srcdir/ogdf-${pkgtreename}-${pkgver}"

# 	# Skip repeated failing GraphCopy test (randomness issues?)
# 	./tests --skip="works using source and target"
# }