PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Alex Talker
# okular-frameworks-git:
# Maintainer: Antonio Rojas
# Contributor Martchus <martchus@gmx.net>

pkgname=okular-git
pkgver=20.08.1.r120.gd78e2ff9e
pkgrel=1
pkgdesc='Universal document viewer'
arch=(i686 x86_64)
url='http://kde.org/applications/graphics/okular/'
license=(GPL)
depends=(kpty kirigami2 discount kdegraphics-mobipocket purpose threadweaver kactivities khtml chmlib djvulibre libspectre poppler-qt5 libkexiv2)
makedepends=(extra-cmake-modules kdoctools git python ebook-tools qca-qt5)
optdepends=('ebook-tools: mobi and epub support' 
            'qca-qt5: support for encrypted ODF documents')
conflicts=(kdegraphics-okular okular okular-frameworks-git)
provides=(okular)
replaces=(okular-frameworks-git)
source=('git+https://invent.kde.org/graphics/okular.git')
sha256sums=('SKIP')

pkgver() {
  cd okular
   git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../okular \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DKDE_INSTALL_LIBDIR=lib
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}