PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Maintainer:

_pkgname="olivia"
pkgname="$_pkgname-git"
pkgver=1.0.beta.r336.g4048134
pkgrel=1
pkgdesc="Elegant Cloud Music Player for Linux Desktop"
url="https://github.com/keshavbhatt/olivia"
license=('MIT')
arch=('i686' 'x86_64')

depends=(
  'ffmpeg'
  'mpv'
  'pv'
  'python'
  'qt5-base'
  'qt5-webkit'
  'socat'
  'taglib'
  'wget'
)
makedepends=(
  'git'
  'qt5-tools'
)

if [ x"$pkgname" == x"$_pkgname" ] ; then
  # normal package
  _pkgsrc="$_pkgname"
  source+=("$_pkgsrc"::"git+$url.git#tag=v${pkgver%%.r*}")
  sha256sums+=('SKIP')

  pkgver() {
    echo "${pkgver%%.r*}"
  }
else
  # git package
  provides=("$_pkgname")
  conflicts=("$_pkgname")

  _pkgsrc="$_pkgname"
  source+=("$_pkgsrc"::"git+$url.git")
  sha256sums+=('SKIP')

  pkgver() {
    cd "$_pkgsrc"
    git describe --long --tags | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
  }
fi

build() {
  mkdir -p build && cd build
  qmake "${srcdir:?}/$_pkgsrc/src/Olivia.pro" PREFIX="${pkgdir:?}/usr" -spec linux-g++ CONFIG+=release
  make
}

package() {
  cd build
  make install # ignores DESTDIR

  install -Dm644 "${srcdir:?}/$_pkgsrc/LICENSE" -t "${pkgdir:?}/usr/share/licenses/${pkgname:?}/"
}