summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6423cc5f0511120ba37c221a4ea7ee5d51563d29 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Davide Depau <davide@depau.eu>
# Contributor: Doug Newgard <scimmia at archlinux dot info>
# Contributor: Jameson Pugh <imntreal@gmail.com>

_pkgname=onedrive
pkgname=$_pkgname-abraunegg-git
pkgver=2.3.3.r4.gfbad4b4
pkgrel=2
epoch=1
pkgdesc="Free OneDrive client written in D - abraunegg's fork"
arch=('i686' 'x86_64')
url='https://github.com/abraunegg/onedrive'
license=('GPL3')
depends=('curl' 'gcc-libs' 'glibc' 'sqlite' 'libnotify')
makedepends=('dmd' 'git')
provides=("onedrive=$pkgver")
conflicts=('onedrive')
source=('git+https://github.com/abraunegg/onedrive.git')
sha256sums=('SKIP')

prepare() {
  sed -i 's/std\.c\./core.stdc./g' $_pkgname/src/sqlite.d
}

pkgver() {
  cd $_pkgname

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd $_pkgname

  ./configure --enable-notifications --enable-completions --prefix=/usr
  make COMPLETIONS=1 NOTIFICATIONS=1 PREFIX=/usr
}

package() {
  make COMPLETIONS=1 NOTIFICATIONS=1 PREFIX=/usr DESTDIR="$pkgdir" -C $_pkgname install
  install -Dm644 $_pkgname/config "$pkgdir/usr/share/onedrive/config.default"
}