blob: 1cf4153da9bde61b31efe4ccf2279661ffa2ac75 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Jonathan Wright <jon@than.io>
# Prior Maintainer: Brian Atkinson <brian@atkinson.mn>
# Prior Maintainer: David Birks <david@birks.dev>
pkgname=opa
pkgver=0.63.0
pkgrel=1
pkgdesc='Command-line utility and REPL for Open Policy Agent'
arch=(x86_64)
url='https://github.com/open-policy-agent/opa'
license=(Apache)
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::https://github.com/open-policy-agent/opa/archive/v$pkgver.tar.gz")
sha256sums=('0639466031325de698c61d55850c35d14a7a260ead5d5a06540ee142950818b0')
build() {
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -modcacherw"
go build \
-ldflags "-X github.com/open-policy-agent/opa/version.Version=$pkgver" \
-o "$pkgname" \
.
mkdir completion
"./$pkgname" completion bash > "completion/$pkgname"
"./$pkgname" completion zsh > "completion/_$pkgname"
"./$pkgname" completion fish > "completion/$pkgname.fish"
}
package() {
install -Dm 755 "$srcdir/$pkgname-$pkgver/$pkgname" "$pkgdir/usr/bin/$pkgname"
install -vDm 644 "$srcdir/$pkgname-$pkgver/completion/$pkgname" -t "$pkgdir/usr/share/bash-completion/completions/"
install -vDm 644 "$srcdir/$pkgname-$pkgver/completion/_$pkgname" -t "$pkgdir/usr/share/zsh/site-functions/"
install -vDm 644 "$srcdir/$pkgname-$pkgver/completion/$pkgname.fish" -t "$pkgdir/usr/share/fish/completions/"
}
|