blob: 71d3fabb86ee0fe03e9e630df929260ed404c1a1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Michael Lass <bevan@bi-co.net>
# Contributor: Konstantin Gizdov <arch at kge dot pw>
# This PKGBUILD is maintained on github:
# https://github.com/michaellass/AUR
pkgname=openafs-modules-dkms
_srcname=openafs
pkgver=1.8.16.1
pkgrel=2
pkgdesc="Kernel module for OpenAFS (dkms)"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.openafs.org"
license=(IPL-1.0)
depends=('dkms' 'libelf' 'openafs>=1.8.12.1-2')
provides=("openafs-modules=$pkgver")
conflicts=('openafs-features-libafs' 'openafs-modules' 'openafs<1.6.6-2')
options=(!emptydirs)
source=(http://openafs.org/dl/openafs/${pkgver}/${_srcname}-${pkgver}-src.tar.bz2
dkms.conf
0001-cf-Ensure-BTF-info-is-created-in-tests-for-Linux.patch
0002-linux-replace-strncpy-with-strscpy.patch)
sha256sums=('cf59067589a295471e3f10f644f0f2165113347cc8b0ad0fbb4123259a2af0a2'
'306408d644e8781f13e09021449cb1ccbba60f69d1d24eca5f8138e9b3e47d8e'
'cce37a4d4da631d3e58d547268e1663640d820c69e3b652d9691b44bcbcbb37b'
'655b91807f6eefe28a6e7fe101baf337d5cc6cd5e6a7eb714ce638920a413fa2')
prepare() {
cd "${srcdir}/${_srcname}-${pkgver}"
# Fix configure checks on Arch Linux
patch -p1 < "${srcdir}"/0001-cf-Ensure-BTF-info-is-created-in-tests-for-Linux.patch
# Add patch for Linux 7.2
patch -p1 < "${srcdir}"/0002-linux-replace-strncpy-with-strscpy.patch
# Only needed when changes to configure were made
./regen.sh -q
}
build() {
cd "${srcdir}/${_srcname}-${pkgver}"
case "$CARCH" in
"i686") sysname=i386_linux26 ;;
"x86_64") sysname=amd64_linux26 ;;
"armv7h") sysname=arm_linux26 ;;
*) error "Unknown architecture '$CARCH'" && false
esac
./configure --prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--libexecdir=/usr/lib \
--disable-fuse-client \
--disable-kernel-module \
--without-swig \
--with-afs-sysname=$sysname
make only_libafs_tree
}
package() {
# install license
install -Dm644 "${srcdir}/${_srcname}-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# install sources
install -dm755 "${pkgdir}/usr/src/${_srcname}-${pkgver}"
mv "${srcdir}/${_srcname}-${pkgver}/libafs_tree/"* "${pkgdir}/usr/src/${_srcname}-${pkgver}"
sed "s/__VERSION__/$pkgver/" "${srcdir}/dkms.conf" > "${pkgdir}/usr/src/${_srcname}-${pkgver}/dkms.conf"
}
|