blob: b03b3396e3b32c6c0d7d360498b1ed2c06a9207c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: frazar0 [at] hotmail (dot) it
# Contributor: chn <g897331845@gmail.com>
# Contributor: George Eleftheriou <eleftg>
# Contributor: eolianoe <eolianoe [at] gmail [DoT] com>
# Contributor: Jiaxi Hu <sftrytry _AT_ gmail _DOT_ com>
# Contributor: Giuseppe Borzi <gborzi _AT_ ieee _DOT_ org>
pkgname=openblas-lapack-static
_PkgName=OpenBLAS
_pkgname=openblas
pkgver=0.3.21
# grep VERSION "${srcdir}/${_PkgName}-${pkgver}"/lapack-netlib/README.md | tail -n 1 | cut -d ' ' -f 2
_lapackver=3.10.1
_blasver=3.8.0
pkgrel=1
pkgdesc="Optimized BLAS library based on GotoBLAS2 1.13 BSD (providing blas, lapack, and cblas)"
arch=('x86_64')
url="http://www.openblas.net/"
license=('BSD')
depends=('gcc-libs')
makedepends=('perl' 'gcc-fortran')
provides=('openblas' "blas=${_blasver}" "lapack=${_lapackver}" "cblas=${_blasver}" "lapacke=${_lapackver}")
conflicts=('openblas' 'blas' 'lapack' 'cblas' 'lapacke')
options=(!emptydirs staticlibs)
source=(${_PkgName}-${pkgver}.tar.gz::https://github.com/xianyi/${_PkgName}/archive/v${pkgver}.tar.gz)
sha256sums=('f36ba3d7a60e7c8bcc54cd9aaa9b1223dd42eaf02c811791c37e8ca707c241ca')
# Add the following line to the _config variable if you want to set the number of make jobs
# MAKE_NB_JOBS=2 \
_config="FC=gfortran USE_OPENMP=1 USE_THREAD=1 \
USE_TLS=1 \
NO_LAPACK=0 BUILD_LAPACK_DEPRECATED=1 \
MAJOR_VERSION=${_lapackver:0:1}"
build(){
cd "${srcdir}/${_PkgName}-${pkgver}"
make ${_config} CFLAGS="${CFLAGS}" libs netlib shared
}
check(){
cd "${srcdir}/${_PkgName}-${pkgver}"
make ${_config} tests
}
package(){
cd "${srcdir}/${_PkgName}-${pkgver}"
make ${_config} PREFIX=/usr DESTDIR="${pkgdir}" install
# Install license
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# Symlink to provide blas, cblas, lapack and lapacke
cd "${pkgdir}/usr/lib/"
# BLAS
ln -sf libopenblas.a libblas.a
ln -sf libopenblas.so libblas.so
ln -sf libopenblas.so libblas.so.${_blasver:0:1}
ln -sf libopenblas.so libblas.so.${_blasver}
# CBLAS
ln -sf libopenblas.a libcblas.a
ln -sf libopenblas.so libcblas.so
ln -sf libopenblas.so libcblas.so.${_blasver:0:1}
ln -sf libopenblas.so libcblas.so.${_blasver}
# LAPACK
ln -sf libopenblas.a liblapack.a
ln -sf libopenblas.so liblapack.so
ln -sf libopenblas.so liblapack.so.${_lapackver:0:1}
ln -sf libopenblas.so liblapack.so.${_lapackver}
# LAPACKE
ln -sf libopenblas.a liblapacke.a
ln -sf libopenblas.so liblapacke.so
ln -sf libopenblas.so liblapacke.so.${_lapackver:0:1}
ln -sf libopenblas.so liblapacke.so.${_lapackver}
}
|