blob: 4e64e0ab2e8ae11c09f035f3ed2355bf31b40ebe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Martins Mozeiko <martins.mozeiko@gmail.com>
# Co-Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=opencl-caps-viewer
pkgver=1.20
pkgrel=2
pkgdesc="OpenCL Hardware Capability Viewer"
arch=("x86_64")
depends=("opencl-icd-loader" "qt5-x11extras")
url="https://opencl.gpuinfo.org/"
makedepends=('git')
license=("GPL-2.0-or-later")
source=("git+https://github.com/SaschaWillems/OpenCLCapsViewer.git#tag=${pkgver}"
"git+https://github.com/KhronosGroup/OpenCL-Headers.git")
sha256sums=("SKIP"
"SKIP")
prepare() {
cd "$srcdir/OpenCLCapsViewer"
git submodule init
git config submodule.OpenCL-Headers.url "$srcdir/OpenCL-Headers"
git -c protocol.file.allow=always submodule update
# Correct binary install path
sed -i 's|target.path = /opt/$${TARGET}/bin|target.path = /usr/bin|g' OpenCLCapsViewer.pro
}
build() {
cd "$srcdir/OpenCLCapsViewer"
qmake-qt5 OpenCLCapsViewer.pro \
DEFINES+=X11 \
CONFIG+=release \
PREFIX=/usr
make
}
package() {
cd "$srcdir/OpenCLCapsViewer"
make INSTALL_ROOT="$pkgdir/" install
install -m644 Resources/icon.png "${pkgdir}"/usr/share/icons/hicolor/256x256/apps/openclCapsViewer.png
}
|