blob: f8753de6b646c0195794fe945ab0d7e2c8a648f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: physkets <physkets@tutanota.com>
# Contributor: James Clark <s1127853@sms.ed.ac.uk>
pkgname=opencoarrays
pkgver=2.1.0
pkgrel=3
pkgdesc="A transport layer for coarray Fortran compilers."
url="http://www.opencoarrays.org/"
arch=('x86_64' 'i686')
license=('BSD')
depends=('mpich' 'gcc-fortran')
makedepends=('cmake')
source=("https://github.com/sourceryinstitute/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('c8e4ce7ddb851fd3eb981836c9e2e1a5de53afe3da1401971cfaf4114edb3af7')
build() {
export PATH="/opt/mpich/bin:$PATH"
cd "${srcdir}/OpenCoarrays-${pkgver}"
mkdir -p build
cd build
CC=gcc FC=gfortran cmake .. \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DMPI_C_COMPILER=/opt/mpich/bin/mpicc \
-DMPI_Fortran_COMPILER=/opt/mpich/bin/mpifort
make
}
check() {
export PATH="/opt/mpich/bin:$PATH"
cd "${srcdir}/OpenCoarrays-${pkgver}/build"
ctest
}
package() {
cd "${srcdir}/OpenCoarrays-${pkgver}/build"
make DESTDIR="${pkgdir}" install
install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|