blob: ebbd278c973b82b88a94e922708deaa72f3de481 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: physkets <physkets // at // tutanota dot com>
# Contributor: James Clark <s1127853@sms.ed.ac.uk>
pkgname=opencoarrays
pkgver=2.5.0
pkgrel=1
pkgdesc="A transport layer for coarray Fortran compilers."
url="http://www.opencoarrays.org/"
arch=('x86_64')
license=('BSD')
depends=('mpich' 'gcc-fortran')
makedepends=('cmake')
source=("https://github.com/sourceryinstitute/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz"{,.asc})
validpgpkeys=('1DB1B5EDE32122B28E56810DCB21118C92A64702') #Izaak Beekman <zbeekman@gmail.com>
sha256sums=('fca62bd93b8fdcb6ee68b9c96d26d93f7440c2da8942a5ddcb14159457454276'
'SKIP' )
build() {
export PATH="/opt/mpich/bin:$PATH"
export LD_LIBRARY_PATH="/opt/mpich/lib:${LD_LIBRARY_PATH}"
cd "${srcdir}/OpenCoarrays-${pkgver}"
mkdir -p build
cd build
CC=gcc FC=gfortran cmake .. \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DMPI_C_COMPILER=/opt/mpich/bin/mpicc \
-DMPI_Fortran_COMPILER=/opt/mpich/bin/mpifort
make
}
check() {
export PATH="/opt/mpich/bin:$PATH"
export LD_LIBRARY_PATH="/opt/mpich/lib:${LD_LIBRARY_PATH}"
cd "${srcdir}/OpenCoarrays-${pkgver}/build"
make test
}
package() {
cd "${srcdir}/OpenCoarrays-${pkgver}/build"
make DESTDIR="${pkgdir}" install
install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|