blob: 17aed0ff52b11048bbcfe709a0bbfd066d12eb51 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=opencore-amr-git
pkgver=0.1.6.r0.g7dba8c3
pkgrel=1
pkgdesc="Open source implementation of the Adaptive Multi Rate (AMR) speech codec"
arch=('i686' 'x86_64')
url="https://opencore-amr.sourceforge.io/"
license=('Apache')
depends=('glibc')
makedepends=('git')
provides=("opencore-amr=$pkgver" 'libopencore-amrnb.so' 'libopencore-amrwb.so')
conflicts=('opencore-amr')
options=('staticlibs')
source=("git+https://git.code.sf.net/p/opencore-amr/code")
sha256sums=('SKIP')
pkgver() {
cd "code"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "code"
autoreconf -fi
./configure \
--prefix="/usr" \
--enable-examples
make
}
check() {
cd "code"
make check
}
package() {
cd "code"
make DESTDIR="$pkgdir" install
}
|