blob: 221b0fc5651d912aee2b6c9a11f307d665270b0b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Andrew Crerar <andrew (at) crerar (dot) io>
# Contributor: Valentin Churavy <v.churavy@gmail.com>
# Contributor: Romain Reignier <rom.reignier@gmail.com>
# Contributor: Fabien Dubosson <fabien.dubosson@gmail.com>
# Contributor: David Manouchehri <david@davidmanouchehri.com>
# Contributor: CHEN Xing <cxcxcxcx@gmail.com>
# Contributor: Martin Imobersteg <martin.imobersteg@gmail.com>
# Contributor: Artyom Smirnov <smirnoffjr@gmail.com>
# Also largely inspired by `opencv` in extra, so including contributors too:
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
_name=opencv
pkgname="$_name-git"
pkgver=3.3.1.r92.gf9ac1665b6
pkgrel=1
pkgdesc="Open Source Computer Vision Library"
url="http://opencv.org/"
license=(BSD)
arch=(i686 x86_64)
depends=(intel-tbb openexr xine-lib libdc1394 hdf5 gst-plugins-base-libs
gtk3 protobuf)
makedepends=(git cmake python2-numpy python-numpy mesa eigen)
optdepends=('opencv-samples'
'hdf5: Support for HDF5 format'
'opencl-icd-loader: For coding with OpenCL'
'python-numpy: Python 3 interface'
'python2-numpy: Python 2 interface')
conflicts=(opencv)
provides=("$_name=$pkgver")
source=('git+https://github.com/opencv/opencv.git'
'git+https://github.com/opencv/opencv_contrib.git')
sha512sums=('SKIP'
'SKIP')
_cmakeopts=('-D WITH_OPENCL=ON'
'-D WITH_OPENGL=ON'
'-D WITH_TBB=ON'
'-D WITH_XINE=ON'
'-D WITH_GSTREAMER=OFF'
'-D BUILD_WITH_DEBUG_INFO=OFF'
'-D BUILD_TESTS=OFF'
'-D BUILD_PERF_TESTS=OFF'
'-D BUILD_EXAMPLES=ON'
'-D INSTALL_C_EXAMPLES=ON'
'-D INSTALL_PYTHON_EXAMPLES=ON'
'-D CMAKE_BUILD_TYPE=Release'
'-D CMAKE_INSTALL_PREFIX=/usr'
'-D CMAKE_SKIP_RPATH=ON')
# SSE only available from Pentium 3 onwards (i686 is way older)
[[ "$CARCH" = 'i686' ]] && \
_cmakeopts+=('-D ENABLE_SSE=OFF'
'-D ENABLE_SSE2=OFF'
'-D ENABLE_SSE3=OFF')
pkgver() {
cd "$srcdir/$_name"
git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}
build() {
mkdir -p build
cd build
cmake ${_cmakeopts[@]} \
-DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib/modules" \
../$_name
make
}
package() {
options=('staticlibs')
cd build
make DESTDIR="$pkgdir" install
# install LICENSE file
install -Dm644 "$srcdir/$_name/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|