PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: piernov <piernov@piernov.org>

pkgname=openeb3
_pkgname=openeb
pkgdesc="Open source SDK for event based cameras by Prophesee with support for EVK1"
pkgver=3.1.2
pkgrel=5
arch=('any')
license=(custom)
url="https://github.com/prophesee-ai/openeb"
depends=(opencv boost eigen libusb glew glfw hdf5 ffmpeg openscenegraph libcanberra)
optdepends=('cuda: machine learning samples')
makedepends=('git')
conflicts=('openeb-git')
provides=('openeb')
source=("${_pkgname}::git+https://github.com/prophesee-ai/openeb#tag=${pkgver}"
  "fix-build.patch"
  "python-version.patch"
  "0001-Fix-build-with-GCC-15.patch"
  "profiling-remove-boost-system.patch")
sha256sums=('2f977d673ae345747d04cd224f8263e6b7f1cde58d46aa43a1bf0425fa548ab7'
            'c6c341a17aab158179d741720fe7b175a9991514ac5d9030ea4b2f1344de55c4'
            '37caae8372a150ea094fd9126020527569925e93dc1f1f6935f6580209db93cc'
            'da2e825583596e81ac9ff29f37f27341c8e1219a0f443ee1c6c725ab0235ac34'
            'de761a59ff5211d28af3fcc57c009de7f2cf142fae3f93f130f203157ca46d04')

prepare() {
  cd "${_pkgname}"
  patch -p1 -i "${srcdir}/fix-build.patch"
  patch -p1 -i "${srcdir}/python-version.patch"
  patch -p1 -i "${srcdir}/0001-Fix-build-with-GCC-15.patch"
  patch -p1 -i "${srcdir}/profiling-remove-boost-system.patch"
}

build() {
  cmake -B build -S "${_pkgname}" \
    -DBUILD_TESTING=off \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -Wno-dev
  cmake --build build --config Release
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}