blob: 46b89825a6907289f8a0fe9e5ae1fcd999b959fa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: iamawacko <iamawacko@protonmail.com>
# Contributor: Dimitris Kiziridis <ragouel at outlook dot com>
# Contributor: rawkode <rawkode@pm.me>
pkgname=openfaas-cli
pkgver=0.17.3
pkgrel=1
pkgdesc="Official CLI for OpenFaaS"
arch=('i686' 'x86_64' 'arm64')
url="https://github.com/openfaas/faas-cli"
license=('MIT')
provides=('faas-cli')
depends=('glibc')
makedepends=('go' 'git')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
sha256sums=('5c4a44589b8988891b8544ff570ae209ec93e037394aacf5a1b225daa2bc176a')
prepare() {
cd "${srcdir}/faas-cli-${pkgver}"
mkdir -p build/
}
build() {
cd "${srcdir}/faas-cli-${pkgver}"
export CGO_LDFLAGS="${LDFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -modcacherw"
go get -d -v ./...
go build -o build ./...
}
package() {
cd "${srcdir}/faas-cli-${pkgver}"
install -Dm755 build/faas-cli "${pkgdir}/usr/bin/faas-cli"
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|