blob: e07afd0e87164d662a64b1a74cf189d959629201 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: mekyt <hello at mek dot yt>
pkgname="openfga"
pkgver=1.17.1
pkgrel=1
pkgdesc="High performance and flexible authorization/permission engine built for developers and inspired by Google Zanzibar"
arch=(
'aarch64'
'i686'
'x86_64'
)
url="https://openfga.dev"
_url="https://github.com/${pkgname}/${pkgname}"
license=(
'Apache-2.0'
)
depends=(
'glibc'
)
makedepends=(
'git'
'go'
)
backup=(
"etc/${pkgname}"
)
_pkgsrc="${_url##*/}"
source=(
"${_pkgsrc}::git+${_url}.git#tag=v${pkgver}"
"${pkgname}."{service,sysusers,tmpfiles,yaml}
)
sha256sums=('c921faf71fa3a7b9ec8e596d3797c38fe67bfc005fb4412d2494754cd4549785'
'6f5b8d7257f4158b3800346d9fa0679e1041c92987b0303f04439a54e3488580'
'0236b9c80bc4a6ca17c0cc5cae1091a0225cdc29163667661353d42927ecb1e7'
'ac8e4f66ab7fd0540f58d3de61940f0dea1494fa05b4b984796c1db41a053ea1'
'1929be63a6466a045939235754e2d2cfd4ca430c304698a6089614c6b8eec6d1')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
go mod download -modcacherw -x
go mod verify
mkdir -p "completions"
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
go build -v -o "build/${pkgname}" -ldflags "\
-X ${_url#https://}/internal/build.Version=v${pkgver} \
-X ${_url#https://}/internal/build.Commit=$(git rev-parse HEAD 2>/dev/null || echo unknown) \
-X ${_url#https://}/internal/build.Date=$(git show -s --format=%cI HEAD 2>/dev/null | date -u -f - +"%Y-%m-%dT%H:%M:%SZ" || echo unknown) \
-X ${_url#https://}/internal/build.ProjectName=${pkgname}" \
./"cmd/${pkgname}"
for _sh in bash fish powershell zsh; do
./"build/${pkgname}" completion "${_sh}" > "completions/${pkgname}.${_sh}"
done
}
# check() {
# cd "${srcdir}/${_pkgsrc}"
# go test ./...
# }
package() {
cd "${srcdir}"
install -vDm644 "${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
install -vDm644 "${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
install -vDm644 "${pkgname}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
install -vDm664 "${pkgname}.yaml" "${pkgdir}/etc/${pkgname}"
cd "${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "CHANGELOG.md" "${pkgdir}/usr/share/doc/${pkgname}/CHANGELOG.md"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "completions"
install -vDm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -vDm644 "${pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${pkgname}.ps1"
install -vDm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
}
|