blob: 3017860aa6630cd0fc149ca92bf1d4ce410eabbe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Tércio Martins <echo dGVyY2lvd2VuZGVsQGdtYWlsLmNvbQo= | base64 -d>
pkgname=openfx-gmic
pkgver=2.4.3
pkgrel=1
arch=('x86_64')
pkgdesc="OpenFX wrapper for the G'MIC framework"
url="https://github.com/NatronGitHub/openfx-gmic"
license=('custom:CeCILL-C' 'custom:CeCILLv2')
depends=('fftw' 'libgl' 'libpng')
makedepends=('openmp')
conflicts=("${pkgname}-git")
_natron_ver="Natron-${pkgver}"
_pkgname="${pkgname}-${_natron_ver}"
_url=${url%/${pkgname}}
source=("${_pkgname}.tar.gz::${url}/archive/refs/tags/${_natron_ver}.tar.gz"
"openfx-${_natron_ver}.tar.gz::${_url}/openfx/archive/refs/tags/${_natron_ver}.tar.gz")
sha512sums=('3ab5d0acbdbfda003f6d465cbcd29bd287cccd536ad1d9d554d5c0422d44b8cd748174c6a9b7b9bdf297d630dbff32113715cccb1e491c1acb7f901069028f0e'
'56fc96d0820d053940336ef3ae9fee4e4386e90c9cede6e5450de66c92220f2670f12b25dfb17aaec621001db140281ab47ee8f3fa5e5915a56cfefe2be813fe')
prepare() {
tar -xzf "openfx-${_natron_ver}.tar.gz" --strip 1 \
-C "${_pkgname}/openfx/"
}
build() {
cd ${_pkgname}
make CONFIG=release \
OPENMP=1
}
package() {
cd ${_pkgname}
install -d "${pkgdir}/usr/OFX/Plugins"
make install PLUGINPATH="${pkgdir}/usr/OFX/Plugins" \
CONFIG=release
mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
for license_file in COPYING Licence_CeCILL-C_V1-en.txt Licence_CeCILL_V2-en.txt; do
install -Dm644 $license_file \
"${pkgdir}/usr/share/licenses/${pkgname}/"
done
}
|