PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=openjpeg-git
pkgver=2.5.3.r7.ge7453e39
pkgrel=1
pkgdesc="An open-source JPEG 2000 codec written in C language"
arch=('i686' 'x86_64')
url="https://github.com/uclouvain/openjpeg"
license=('BSD-2-Clause')
depends=('glibc' 'lcms2' 'libpng' 'libtiff' 'zlib')
makedepends=('git' 'cmake' 'doxygen' 'jbigkit')
provides=("openjpeg2=$pkgver")
conflicts=('openjpeg2')
options=('staticlibs')
source=("git+https://github.com/uclouvain/openjpeg.git")
sha256sums=('SKIP')


pkgver() {
  cd "openjpeg"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "openjpeg"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DBUILD_DOC=ON \
    ./
  cmake --build "_build"
}

package() {
  cd "openjpeg"

  DESTDIR="$pkgdir" cmake --install "_build"
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/openjpeg2"
}