PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=openjpeg-git
pkgver=2.3.0.r2.gacd91508
pkgrel=1
pkgdesc="An open-source JPEG 2000 codec written in C language"
arch=('i686' 'x86_64')
url="https://github.com/uclouvain/openjpeg"
license=('BSD')
depends=('glibc' 'zlib' 'libpng' 'libtiff' 'lcms2')
makedepends=('git' 'cmake' 'doxygen')
provides=('openjpeg2')
conflicts=('openjpeg2')
options=('staticlibs')
source=("git+https://github.com/uclouvain/openjpeg.git")
sha256sums=('SKIP')


prepare() {
  cd "openjpeg"

  mkdir -p "_build"

  # Install doxygen docs to the right directory
  sed -i 's:DESTINATION\ share/doc:DESTINATION\ share/doc/openjpeg2:' "doc/CMakeLists.txt"
}

pkgver() {
  cd "openjpeg"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "openjpeg/_build"

  cmake -DCMAKE_INSTALL_PREFIX="/usr" -DCMAKE_BUILD_TYPE=Release -DBUILD_DOC=on ../
  make
}

package() {
  cd "openjpeg/_build"

  make DESTDIR="$pkgdir" install

  install -Dm644 "../LICENSE" "$pkgdir/usr/share/licenses/openjpeg2/LICENSE"
  rm -r "$pkgdir/usr/share/doc"/openjpeg-2.*
}