blob: e54b01e13bac05ace531e102e96ac50d9c4590f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Sandy Carter <bwrsandman@gmail.com>
# PKGBUILD source: https://github.com/bwrsandman/pkgbuild/tree/master/openmw-git
pkgname=openmw-git
pkgver=0.46.0.r1477.gdc82cb61f
pkgrel=1
pkgdesc="An open-source engine reimplementation for the role-playing game Morrowind."
arch=('i686' 'x86_64')
url="http://www.openmw.org"
license=('GPL3' 'MIT' 'custom')
depends=('openal' 'openscenegraph' 'mygui' 'bullet-multithreaded' 'qt5-base' 'ffmpeg' 'sdl2' 'unshield' 'libxt' 'boost-libs')
optdepends=('openscenegraph-openmw-git: experimental performance enhancements for OpenMW that are too controversial to be included in the general purpose OSG project')
makedepends=('git' 'cmake' 'boost')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
source=('git+https://gitlab.com/OpenMW/openmw.git')
sha1sums=('SKIP')
pkgver() {
cd "${srcdir}/${pkgname%-git}"
_tag="$(git describe --tags $(git rev-list --tags --max-count=1) | sed 's/openmw-//')"
_numcommits="$(git rev-list `git rev-list --tags --no-walk --max-count=1`..HEAD --count)"
_hash="$(git rev-parse --short HEAD)"
printf "%s.r%s.g%s" "$_tag" "$_numcommits" "$_hash"
}
build() {
cd "${srcdir}/${pkgname%-git}"
cmake -DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=RelWithDebInfo \
-DDESIRED_QT_VERSION=5
make
}
package() {
cd "${srcdir}/${pkgname%-git}"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|