blob: 7aa1f116efd0c1ababb86fe9f8dfc176a48ea092 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Evert "Diamond" Prants <evert@lunasqu.ee>
# Contributor: Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor: Sébastien Luttringer
# Contributor: kevku <kevku@msn.com>
# Contributor: Andrew Rembrandt <andrew@rembrandt.me.uk>
_pkgname=OpenSC
pkgname=opensc-git
pkgver=0.21.0+196+g991bb8a14
pkgrel=1
pkgdesc='Tools and libraries for smart cards'
arch=('x86_64')
url='https://github.com/OpenSC/OpenSC/wiki'
license=('LGPL')
backup=('etc/opensc.conf')
makedepends=('docbook-xsl' 'git' 'bash-completion')
depends=('pcsclite' 'libltdl' 'glib2')
options=('!emptydirs')
conflicts=('opensc')
provides=('opensc')
source=("git+https://github.com/OpenSC/OpenSC.git#branch=master")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --tags | sed 's/^opensc-//;s/-/+/g'
}
build() {
cd "$srcdir/$_pkgname"
_sheetdir=(/usr/share/xml/docbook/xsl-stylesheets-*)
./bootstrap
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--enable-man \
--enable-doc \
--enable-readline \
--enable-openssl \
--enable-pcsc \
--enable-zlib \
--enable-sm \
--with-xsl-stylesheetsdir="$_sheetdir"
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package(){
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir" install
install -D -m644 etc/opensc.conf "$pkgdir/etc/opensc.conf"
}
|