PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: Ariadna Ardere arxofari@proton.me
pkgname=openshockclock-git
pkgver=r13.78f1e56
pkgrel=1
pkgdesc="GTK4/Libadwaita alarm clock application for OpenShock devices"
arch=('any')
url="https://github.com/arxari/openshockclock-gtk"
license=('GPL3')
depends=(
    'python'
    'python-gobject'
    'gtk4'
    'libadwaita'
    'python-requests'
    'python-dotenv'
)
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/arxari/openshockclock-gtk.git")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/openshockclock-gtk"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
    cd "$srcdir/openshockclock-gtk"
    
    install -dm755 "$pkgdir/usr/bin"
    install -dm755 "$pkgdir/usr/share/${pkgname%-git}"
    install -dm755 "$pkgdir/usr/share/applications"
    install -dm755 "$pkgdir/usr/share/icons/hicolor/scalable/apps"
    
    install -Dm755 openshockclock-gtk.py "$pkgdir/usr/share/${pkgname%-git}/"
    
    install -Dm644 icons/openshockclock.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/${pkgname%-git}.svg"
    
    cat > "$pkgdir/usr/share/applications/${pkgname%-git}.desktop" << EOF
[Desktop Entry]
Name=OpenShockClock
Comment=Alarm clock application for OpenShock devices
Exec=/usr/bin/openshockclock
Icon=${pkgname%-git}
Terminal=false
Type=Application
Categories=Utility;
EOF

    chmod 644 "$pkgdir/usr/share/applications/${pkgname%-git}.desktop"

    cat > "$pkgdir/usr/bin/openshockclock" << EOF
#!/bin/sh
exec python /usr/share/${pkgname%-git}/openshockclock-gtk.py "\$@"
EOF

    chmod 755 "$pkgdir/usr/bin/openshockclock"
}