blob: 33552d5d71e8fb92f43da76c965e617c2e140766 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Maintainer: Shalygin Konstantin <k0ste@k0ste.ru>
# Contributor: Shalygin Konstantin <k0ste@k0ste.ru>
pkgname='openvpn-auth-oauth2'
pkgver='1.28.3'
pkgrel='1'
pkgdesc='A Plugin/management interface client for OpenVPN server to handle an OIDC based single sign-on (SSO) auth flows'
arch=('x86_64' 'aarch64')
_uri="github.com/jkroepke"
url="https://${_uri}/${pkgname}"
license=('MIT')
makedepends=('go')
depends=('openvpn>=2.6.2')
source=("${pkgname}-${pkgver}.tar.gz::https://codeload.${_uri}/${pkgname}/tar.gz/refs/tags/v${pkgver}")
sha256sums=('8e987a9f575d20f2e4e80abf833104613f50398e9578f7168cd583e2cb6b7082')
backup=("etc/conf.d/${pkgname}"
"etc/${pkgname}/config.yaml")
prepare() {
export GOPATH="${srcdir}/gopath"
export GOBIN="${GOPATH}/bin"
export GOCACHE="${srcdir}/cache/go-cache"
export GOMODCACHE="${srcdir}/cache/go"
export GOTMPDIR="${srcdir}"
eval "$(go env | grep -e "GOHOSTOS" -e "GOHOSTARCH")"
mkdir -p "${GOPATH}/src/${_uri}"
ln -snf "${srcdir}/${pkgname}-${pkgver}" "${GOPATH}/src/${_uri}/${pkgname}"
sed -i \
-e 's|/etc/sysconfig|/etc/conf.d|g' \
-e 's|CapabilityBoundingSet=|CapabilityBoundingSet=CAP_NET_BIND_SERVICE|g' \
-e 's|AmbientCapabilities=|AmbientCapabilities=CAP_NET_BIND_SERVICE|g' \
-e '/PrivateUsers=true/d' \
"${pkgname}-${pkgver}/packaging/usr/lib/systemd/system/${pkgname}.service"
}
build() {
cd "${GOPATH}/src/${_uri}/${pkgname}"
GOOS="${GOHOSTOS}" GOARCH="${GOHOSTARCH}" BUILDTAGS="no_otel"
for e in "cmd" "lib"
do
if [[ "${e}" == "lib" ]]
then
mode="c-shared"
outname="${pkgname}.so"
else
mode="pie"
outname="${pkgname}"
fi
go build -x \
-buildmode="${mode}" \
-trimpath \
-mod="readonly" \
-modcacherw \
-ldflags "-linkmode external -extldflags '${LDFLAGS}' \
-X ${_uri}/${pkgname}/internal/version.Version=${pkgver} \
-X ${_uri}/${pkgname}/internal/version.Commit=$(git rev-parse HEAD) \
-X ${_uri}/${pkgname}/internal/version.Date=$(date -u '+%Y%m%d-%H:%M:%S' --date=@${SOURCE_DATE_EPOCH})" \
-o "${outname}" \
"./${e}/${pkgname}"
done
}
check() {
cd "${GOPATH}/src/${_uri}/${pkgname}"
go test -modcacherw -race ./...
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm0644 "LICENSE.txt" -t "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm0755 "${pkgname}" -t "${pkgdir}/usr/bin"
install -Dm0755 "${pkgname}.so" -t "${pkgdir}/usr/lib/openvpn/plugins"
install -Dm0644 "${pkgname}.h" -t "${pkgdir}/usr/include"
pushd "packaging"
install -Dm0644 "etc/${pkgname}/config.yaml" -t "${pkgdir}/etc/${pkgname}"
install -Dm0644 "etc/sysconfig/${pkgname}" -t "${pkgdir}/etc/conf.d"
install -Dm0644 "usr/lib/systemd/system/${pkgname}.service" -t "${pkgdir}/usr/lib/systemd/system"
install -Dm0644 "usr/lib/sysusers.d/${pkgname}.conf" -t "${pkgdir}/usr/lib/sysusers.d"
}
|