blob: 2912e122506d119c8c4c74ebc1b807228379d880 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Maintainer: s3rj1k <evasive dot gyron at gmail dot com>
# Do not forget to run `makepkg --printsrcinfo > .SRCINFO`
_pkgname=openvpn
_pkgver=2.6.7
pkgname=${_pkgname}-password-save
pkgver=2.6.7+53c90333
pkgrel=1
pkgdesc='OpenVPN with enable-password-save option'
arch=('x86_64')
url='https://openvpn.net/index.php/open-source.html'
license=('custom')
depends=('openssl' 'lzo' 'lz4' 'systemd-libs' 'libsystemd.so' 'pkcs11-helper' 'libpkcs11-helper.so')
conflicts=('openvpn')
provides=('openvpn')
optdepends=('easy-rsa: easy CA and certificate handling'
'pam: authenticate via PAM')
makedepends=('git' 'systemd' 'python-docutils')
install=openvpn.install
validpgpkeys=('F554A3687412CFFEBDEFE0A312F5F7B42F2B01E7' # OpenVPN - Security Mailing List <security@openvpn.net>
'B62E6A2B4E56570B7BDC6BE01D829EFECA562812') # Gert Doering <gert@v6.de>
source=("git+https://github.com/OpenVPN/openvpn.git#tag=v${_pkgver}?signed"
'0001-unprivileged.patch'
'sysusers.conf'
'tmpfiles.conf')
sha256sums=('SKIP'
'77874824d96c1fd6c14259a6ea16232ae574dda3d5adba1798ccd6c93694846c'
'3646b865ac67783fafc6652589cfe2a3105ecef06f3907f33de5135815f6a621'
'b1436f953a4f1be7083711d11928a9924993f940ff56ff92d288d6100df673fc')
pkgver() {
cd "${srcdir}/${_pkgname}"
printf "%s+%s" "${_pkgver}" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}"/${_pkgname}
# https://www.mail-archive.com/openvpn-devel@lists.sourceforge.net/msg19302.html
sed -i '/^CONFIGURE_DEFINES=/s/set/env/g' configure.ac
# start with unprivileged user and keep granted privileges
patch -Np1 < ../0001-unprivileged.patch
autoreconf --force --install
}
build() {
mkdir "${srcdir}"/build
cd "${srcdir}"/build
"${srcdir}"/openvpn/configure \
--prefix=/usr \
--sbindir=/usr/bin \
--enable-pkcs11 \
--enable-plugins \
--enable-systemd \
--enable-password-save \
--enable-x509-alt-username
make
}
check() {
cd "${srcdir}"/build
make check
}
package() {
cd "${srcdir}"/build
# Install openvpn
make DESTDIR="${pkgdir}" install
# Install sysusers and tmpfiles files
install -D -m0644 ../sysusers.conf "${pkgdir}"/usr/lib/sysusers.d/openvpn.conf
install -D -m0644 ../tmpfiles.conf "${pkgdir}"/usr/lib/tmpfiles.d/openvpn.conf
# Install license
install -d -m0755 "${pkgdir}"/usr/share/licenses/openvpn/
ln -sf /usr/share/doc/openvpn/{COPYING,COPYRIGHT.GPL} "${pkgdir}"/usr/share/licenses/openvpn/
cd "${srcdir}"/${_pkgname}
# Install examples
install -d -m0755 "${pkgdir}"/usr/share/openvpn
cp -r sample/sample-config-files "${pkgdir}"/usr/share/openvpn/examples
# Install contrib
for FILE in $(find contrib -type f); do
case "$(file --brief --mime-type --no-sandbox "${FILE}")" in
"text/x-shellscript")
install -D -m0755 "${FILE}" "${pkgdir}/usr/share/openvpn/${FILE}" ;;
*)
install -D -m0644 "${FILE}" "${pkgdir}/usr/share/openvpn/${FILE}" ;;
esac
done
}
|