blob: debd59d4e4afadbcbeba5a5069ae280d5fcedf33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
pkgname=openwsman
pkgver=2.6.0
pkgrel=1
pkgdesc="Opensource Implementation of WS-Management"
arch=('i686' 'x86_64')
url="https://$pkgname.github.io/"
license=('BSD')
depends=('libxml2' 'sblim-sfcc')
makedepends=('cmake' 'swig'
'perl'
'python2'
'ruby' 'ruby-docs')
optdepends=('perl: for perl bindings'
'python2: for python bindings'
'ruby: for ruby bindings')
backup=("etc/$pkgname/$pkgname.conf"
"etc/$pkgname/${pkgname}_client.conf"
"etc/$pkgname/ssleay.cnf"
"etc/pam.d/$pkgname")
source=("$pkgname-$pkgver.tar.gz::https://github.com/Openwsman/$pkgname/archive/v$pkgver.tar.gz")
md5sums=('824834a86040b98b03f3fc0f7f62e853')
prepare() {
cd "$pkgname-$pkgver"
rm -rf build
mkdir build
sed -e 's/python/python2/' -i bindings/python/tests/run
}
build() {
cd "$pkgname-$pkgver"/build
cmake -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_SKIP_INSTALL_RPATH=ON \
-DPACKAGE_ARCHITECTURE=$CARCH \
-DLIB=lib \
-DBUILD_RUBY_GEM=OFF \
-DBUILD_JAVA=OFF \
-DPYTHON_EXECUTABLE=/usr/bin/python2 \
..
make
}
# TODO: find out why tests fail for python/perl/ruby bindings
# and report a bug upstream if needed
#check() {
# cd "$pkgname-$pkgver"/build
# make ARGS="-V" test
#}
package() {
cd "$pkgname-$pkgver"/build
make DESTDIR="$pkgdir/" install
install -Dm644 ../COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
mv "$pkgdir/usr/sbin" "$pkgdir/usr/bin"
install -dm755 "$pkgdir/usr/share/doc/$pkgname"
mv "bindings/ruby/html/" "$pkgdir/usr/share/doc/$pkgname/rdoc"
install -D -m644 ../README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# vim: set ft=sh ts=4 sw=4 noet:
|