blob: 97a33fc006c73e66cd63be676f3749f184b66aff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: BlackEagle < ike DOT devolder AT gmail DOT com >
pkgname=opera-developer-ffmpeg-codecs
pkgver=60.0.3107.4
pkgrel=1
pkgdesc="additional support for proprietary codecs for opera-developer"
arch=('x86_64')
url="https://ffmpeg.org/"
license=('LGPL2.1')
depends=('gcc-libs' 'zlib')
makedepends=(
'gtk3' 'libexif' 'libxss' 'ninja' 'nss' 'pciutils' 'python2'
'xdg-utils'
)
options=('!strip')
source=(
"https://commondatastorage.googleapis.com/chromium-browser-official/chromium-$pkgver.tar.xz"
'chromium-last-commit-position-r1.patch'
'https://raw.githubusercontent.com/gentoo/gentoo/master/www-client/chromium/files/chromium-FORTIFY_SOURCE-r1.patch'
'https://raw.githubusercontent.com/gentoo/gentoo/master/www-client/chromium/files/chromium-gn-bootstrap-r7.patch'
)
sha512sums=('0c2e6a2496105f026f8d4cf42c5eabfac1f513385c8ace9070f1c9a7ebbcd62190d30857a7f9cc8aed3e590a57816029e04813a7876d47f00ea0e1302f5a8556'
'8f63366ca998e3ee06a79c6df5b4454707bd9865913ecde2f79fcb49fdd86d291f678b9f21807e4eb61d15497cdbe4a4bdc06637882e708f34f6804453bdfd41'
'ab16fdbae0bbbb5756d46492025c7f29a0c78648026ae4bfcca77bf400fea4fb6b4f5ac45b40351c36dd17c81a3a636a13622a7791370c753a112f36418f841b'
'dc169048f99491e864c42eb553b527dff3fbcee39b9a8efafeef5aa77f9bb528d4a0499b2d582b9b1085f6f4098abcfd6f42dd59aa1a1ce30159ca9da04d77da')
prepare() {
cd "$srcdir/chromium-$pkgver"
# Use Python 2
find . -name '*.py' -exec sed -r 's|/usr/bin/python$|&2|g' -i {} +
find . -name '*.py' -exec sed -r 's|/usr/bin/env python$|&2|g' -i {} +
# There are still a lot of relative calls which need a workaround
[[ -d "$srcdir/python2-path" ]] && rm -rf "$srcdir/python2-path"
mkdir "$srcdir/python2-path"
ln -s /usr/bin/python2 "$srcdir/python2-path/python"
# chromium 46 gives an error about a missing file
# workaround create empty
touch chrome/test/data/webui/i18n_process_css_test.html
patch -p1 -i "$srcdir/chromium-last-commit-position-r1.patch"
patch -p1 -i "$srcdir/chromium-FORTIFY_SOURCE-r1.patch"
patch -p1 -i "$srcdir/chromium-gn-bootstrap-r7.patch"
}
build() {
cd "$srcdir/chromium-$pkgver"
export PATH="$srcdir/python2-path:$PATH"
local args="ffmpeg_branding=\"ChromeOS\" proprietary_codecs=true enable_hevc_demuxing=true use_gconf=false use_gio=false use_gnome_keyring=false use_pulseaudio=false link_pulseaudio=false use_kerberos=false use_cups=false use_sysroot=false use_gold=false use_allocator=\"none\" linux_use_bundled_binutils=false fatal_linker_warnings=false treat_warnings_as_errors=false enable_nacl=false enable_nacl_nonsfi=false is_clang=false clang_use_chrome_plugins=false is_component_build=true is_debug=false symbol_level=0"
python2 tools/gn/bootstrap/bootstrap.py -v --gn-gen-args "$args"
out/Release/gn gen out/Release -v --args="$args" --script-executable=/usr/bin/python2
ninja -C out/Release -v media/ffmpeg
}
package() {
cd "$srcdir/chromium-$pkgver"
install -Dm644 out/Release/libffmpeg.so \
"$pkgdir/usr/lib/opera-developer/lib_extra/libffmpeg.so"
}
# vim:set ts=2 sw=2 et:
|