blob: 2dfec109636e741b968d1abcee9106c927ed018c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgbase="optim"
pkgname=(
"${pkgbase}-common"
"${pkgbase}-armadillo"
"${pkgbase}-eigen"
)
_commit="f9d9357169ce4b497a677faa9ce85e901e77275d" # 3.1.3
pkgver=3.1.3
pkgrel=3
pkgdesc="Lightweight C++ library of numerical optimization methods for nonlinear functions"
arch=(
'x86_64'
)
url="https://optimlib.readthedocs.io/"
_url="https://github.com/kthohr/${pkgbase}"
license=(
'Apache-2.0'
)
makedepends=(
'armadillo'
'basematrixops'
'blas'
'eigen>=3.4.0'
'lapack'
)
_pkgsrc="${_url##*/}-${_commit}"
source=(
"${_url}/archive/${_commit}/${_pkgsrc}.tar.gz"
)
sha256sums=('3809f753fc75c007c55ee995264c72487415a22dacc0846ba8ac0c1d1c24b91a')
prepare() {
cd "${srcdir}"
find "${_pkgsrc}" -type f -exec \
sed -i 's|BaseMatrixOps/include|BaseMatrixOps|g' "{}" +
rm -rf "${_pkgsrc}/include/BaseMatrixOps"
cp -a "${_pkgsrc}" "${_pkgsrc}-armadillo"
cp -a "${_pkgsrc}" "${_pkgsrc}-eigen"
}
build() {
export EIGEN_INCLUDE_PATH='/usr/include/eigen3'
local configure_options=(
-i "/usr"
-o "${CXXFLAGS} ${LDFLAGS}"
-p
)
cd "${srcdir}/${_pkgsrc}-armadillo"
./configure "${configure_options[@]}" -l "arma"
make "CXX_STD=-std=c++14"
cd "${srcdir}/${_pkgsrc}-eigen"
./configure "${configure_options[@]}" -l "eigen"
make
}
_package_common() {
cd "${srcdir}/${_pkgsrc}-${1}"
sed -i "s|^INSTALL_PATH=.*|INSTALL_PATH=${pkgdir}/usr|g" 'Makefile'
install -vd "${pkgdir}/usr/lib"
make install
}
package_optim-common() {
pkgdesc+=" (common files)"
arch=(
'any'
)
_package_common "armadillo"
rm -rf "${pkgdir}/usr/lib"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgbase}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgbase}/LICENSE"
}
package_optim-armadillo() {
pkgdesc+=" (${pkgname#"${pkgbase}-"} wrapper)"
depends=(
"${pkgbase}-common>=${pkgver}-${pkgrel}"
'armadillo'
'blas'
'glibc'
'lapack'
'libgcc'
'libgomp'
'libstdc++'
)
provides=(
"${pkgbase}=${pkgver}"
)
conflicts=(
"${pkgbase}"
)
_package_common "${pkgname#"${pkgbase}-"}"
rm -rf "${pkgdir}/usr/include"
}
package_optim-eigen() {
pkgdesc+=" (${pkgname#"${pkgbase}-"} wrapper)"
depends=(
"${pkgbase}-common>=${pkgver}-${pkgrel}"
'eigen>=3.4.0'
'glibc'
'libgcc'
'libgomp'
'libstdc++'
)
provides=(
"${pkgbase}=${pkgver}"
)
conflicts=(
"${pkgbase}"
)
_package_common "${pkgname#"${pkgbase}-"}"
rm -rf "${pkgdir}/usr/include"
}
|