blob: 3a7427809e897a28db337a430d67f6e41ae1063b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Aleksandar Trifunović <akstrfn at gmail dot com>
pkgname=or-tools
pkgver=7.3
pkgrel=1
pkgdesc="Google's Operations Research tools."
arch=('x86_64')
url="https://github.com/google/or-tools"
license=('Apache')
depends=('gcc-libs' 'protobuf' 'gflags' 'google-glog' 'coin-or-cbc' 'protobuf')
makedepends=('cmake' 'pkgconf' 'git')
source=("https://github.com/google/or-tools/archive/v${pkgver}.tar.gz"
"pkg-conf.patch")
sha256sums=('b87922b75bbcce9b2ab5da0221751a3c8c0bff54b2a1eafa951dbf70722a640e'
'177a5f656e6571ab60634167d47d0924e0c71c53680b620023bd9e76e36b9b82')
conflicts=('python-or-tools') # because it copies libortools.so to usr/lib
prepare() {
cd "$pkgname-$pkgver"
patch -Np1 -i "$srcdir/pkg-conf.patch"
cmake -H. -Bbuild \
-DCMAKE_C_FLAGS:STRING="${CFLAGS}" \
-DCMAKE_CXX_FLAGS:STRING="${CXXFLAGS}" \
-DCMAKE_EXE_LINKER_FLAGS:STRING="${LDFLAGS}" \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DBUILD_PYTHON=OFF \
-DBUILD_absl=ON
}
build() {
cd "$pkgname-$pkgver"
cmake --build build
}
check() {
cd "$pkgname-$pkgver"
cmake --build build -- test
}
package() {
cmake --build "$pkgname-$pkgver/build" -- DESTDIR="$pkgdir" install
install -d -m 755 "$pkgdir/usr/share/examples"
cp -a "$pkgname-$pkgver/examples/cpp" "$pkgdir/usr/share/examples/cpp"
rm "$pkgdir"/usr/share/examples/cpp/{BUILD,CMakeLists.txt}
}
|