PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: BasedUser <route@baseduser.eu.org>
# Co-maintainer: Egor Vorontsov <sdoregor@sdore.me>

pkgname=orbitfight
pkgver=0.9
pkgrel=2
pkgdesc="A game in C++ written with SFML, very in-development"
arch=('x86_64')
url="https://github.com/Ilya246/${pkgname}"
license=('GPL3')
depends=('ttf-hack')
makedepends=('sfml' 'gendesk' 'git')
source=("git+${url}.git#tag=${pkgver}")
sha256sums=('SKIP')

prepare() {
	cd "${srcdir}/${pkgname}"

	gendesk -f --pkgname "${pkgname}" --pkgdesc "${pkgdesc}"
}

build() {
	cd "${srcdir}/${pkgname}"

	make
}

package() {
	cd "${srcdir}/${pkgname}"

	install -Dm755 "${pkgname}" -t "${pkgdir}/usr/lib/${pkgname}/"
	install -d "${pkgdir}/usr/lib/${pkgname}/assets"
	ln -s "/usr/share/fonts/TTF/Hack-Regular.ttf" "${pkgdir}/usr/lib/${pkgname}/assets/font.ttf"

	install -d "${pkgdir}/usr/bin"
	ln -s "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/"

	install -Dm644 'SERVERS.md' -t "${pkgdir}/usr/share/${pkgname}/"

	install -Dm644 "${pkgname}.desktop" -t "${pkgdir}/usr/share/applications/"
}