blob: 74e1b844346181dec6b0ed25f6d6cecb1d51cd33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
pkgname=orbment-git
pkgver=r505.01dcfff
pkgrel=2
pkgdesc='modular wayland compositor based on wlc'
url='https://github.com/Cloudef/orbment'
arch=('i686' 'x86_64')
license=('GPL')
options=('debug' '!strip')
depends=('wlc')
makedepends=('git' 'cmake' 'libpng')
optdepends=('weston: test weston clients in orbment'
'bemenu: dynamic menu similar to dmenu for launching programs'
'libpng: PNG screenshot compression')
provides=('orbment')
conflicts=('orbment')
source=('git+https://github.com/Cloudef/orbment'
'git+https://github.com/Cloudef/chck'
'git+https://github.com/Cloudef/inihck')
install='orbment-git.install'
sha1sums=('SKIP' 'SKIP' 'SKIP')
pkgver() {
cd orbment
printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd orbment
git submodule init
git config submodule.chck.url "$srcdir"/chck
git config submodule.lib/inihck.url "$srcdir"/inihck
git submodule update lib/chck lib/inihck
}
build() {
cd orbment
cmake -DCMAKE_BUILD_TYPE=Upstream \
-DCMAKE_INSTALL_LIBDIR=/usr/lib \
-DCMAKE_INSTALL_PREFIX=/usr \
-DSOURCE_CHCK=ON
make
}
package() {
cd orbment
make DESTDIR="$pkgdir" install
}
|