PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: acxz <akashpatel2008 at yahoo dot com>
# Contributor: Sven Schneider <archlinux.sandmann@googlemail.com>

pkgname=orocos-kdl-python-git
pkgver=r931.546d04d
pkgrel=1
pkgdesc="The Kinematics and Dynamics Library is a framework for modelling and computation of kinematic chains (Python binding)"
arch=('i686' 'x86_64')
url="http://www.orocos.org/kdl"
license=('GPL')
depends=(orocos-kdl python-sip)
makedepends=(cmake)
provides=(orocos-kdl-python)
conflicts=(orocos-kdl-python)
source=(git+https://github.com/orocos/orocos_kinematics_dynamics)
sha256sums=('SKIP')

_dir=orocos_kinematics_dynamics
_pkgname=python_orocos_kdl

pkgver() {
  cd "${srcdir}/${_dir}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${srcdir}/${_dir}/${_pkgname}"

  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DBUILD_PYKDL_PYBIND11=OFF \
        .

  make
}

package() {
  cd "${srcdir}/${_dir}/${_pkgname}"
  make DESTDIR="${pkgdir}" install
}