PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Contributor: Guillaume Horel <guillaume.horel@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Jaroslaw Swierczynski <swiergot@aur.archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=ortp-git
_pkgname=ortp
pkgver=4.5.0.alpha.r7.g607b2e7
pkgrel=1
pkgdesc="A Real-time Transport Protocol (RTP) library"
arch=('x86_64')
url="https://github.com/BelledonneCommunications/ortp"
license=('GPL3')
conflicts=('ortp')
provides=("ortp=$pkgver")
depends=('bctoolbox>=4.4.0')
makedepends=('cmake' 'git')
source=("git+https://github.com/BelledonneCommunications/ortp.git")
sha256sums=('SKIP')

pkgver() {
    cd "${_pkgname}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/; s/-/./g'
}

build() {
  cmake -B build "${_pkgname}" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DENABLE_STATIC="NO" \
    -DCMAKE_SKIP_INSTALL_RPATH=ON \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="${pkgdir}" -C build install
}