blob: e617f26f3bef4054a1a00b6f4666355ab16cc3fc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer : Firef0x <Firefgx {at) gmail [dot} com>
# Contributor : Firef0x <Firefgx {at) gmail [dot} com>
# Contributor : Bernhard Walle <bwalle.de: bernhard >
# Contributor : Jesse Jaara <gmail.com, mail.ru: jesse.jaara>
# Contributor : Armin Wehrfritz
# Contributor : Patrick McCarty <pnorcks at gmail dot com>
pkgname=osc
pkgver=0.151.2
pkgrel=2
pkgdesc="Command line client for the openSUSE Build Service"
arch=(any)
url="https://github.com/openSUSE/osc"
license=('GPL2')
depends=('python2'
'python2-m2crypto'
'urlgrabber')
optdepends=('obs-build: required to run local builds'
'obs-service-format_spec_file: for running the format_spec_file source service'
'obs-service-download_files: for running the download_files source service')
conflicts=('osc-git' 'osc-bash-completion' 'zsh-completion-osc')
replaces=('osc-bash-completion' 'zsh-completion-osc')
source=("https://github.com/openSUSE/${pkgname}/archive/${pkgver}.tar.gz"
"_osc::http://sourceforge.net/p/zsh/code/ci/master/tree/Completion/openSUSE/Command/_osc?format=raw")
sha256sums=('51a3e2f9230addfa5814766eb2a78b4230ad5f5760ea4ac12a8d7d44d51c025f'
'7b048c4af5fc21130912322f7e905fa17fc2a0f8db76a981d440664eef34fb09')
prepare() {
# Add 'Arch_Core' and 'Arch_Extra' as osc build targets
sed -i "s|SLE_11_SP2|SLE_11_SP2 Arch_Core Arch_Extra|" _osc
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
python2 setup.py build
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
python2 setup.py install --root="${pkgdir}/" --optimize=1
cd "${pkgdir}/usr/bin"
ln -s osc-wrapper.py osc
cd -
install -Dm644 dist/complete.sh "${pkgdir}/usr/share/bash-completion/completions/osc"
install -Dm755 dist/osc.complete "${pkgdir}/usr/lib/osc/complete"
install -Dm644 ../_osc "${pkgdir}/usr/share/zsh/site-functions/_osc"
}
# vim:set sts=2 ts=2 sw=2 et:
|