PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: David Runge <dvzrv@archlinux.org>

pkgname=osmid
pkgver=0.8.0
pkgrel=2
pkgdesc="A lightweight, portable, easy to use tool to convert MIDI to OSC and OSC to MIDI"
arch=(x86_64)
url="https://github.com/llloret/osmid"
license=(
  GPL2
  MIT
)
groups=(pro-audio)
depends=(
  gcc-libs
  glibc
)
makedepends=(
  alsa-lib
  cmake
  libx11
)
source=($url/archive/v$pkgver/$pkgname-v$pkgver.tar.gz)
sha512sums=('279159790c0214780576cca6483883f71c19923a0bb623b62d7ea6f9ac08f82144c09b1237ffafcf8bba88fbd4fee3bd956570dee8f5f160c88538ce18ccaf8e')
b2sums=('3544d7a4de0ba1a82ad8d42ff9997cc518ded825ffa73491e665552769047005f97ff52138e3b5653beb37d57ab336c3bfc9aa68527c5646b60c132e8af61117')

build() {
  local cmake_options=(
    -B build
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr
    -S $pkgname-$pkgver
    -W no-dev
  )

  cmake "${cmake_options[@]}"
  cmake --build build --verbose
}

check() {
  ctest --test-dir build --output-on-failure
}

package() {
  depends+=(
    alsa-lib libasound.so
  )

  DESTDIR="$pkgdir" cmake --install build
  install -vDm 644 $pkgname-$pkgver/LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname-$pkgver/README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}