blob: 3f7c6218a8c2e72c48d7f0a6f4bdf6241254552f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
pkgname=ostree-git
_pkgname=ostree
pkgver=2020.8+8+g024b169a
pkgrel=1
pkgdesc="Operating system and container binary deployment and upgrades"
url="https://ostree.readthedocs.org/en/latest/"
arch=(x86_64)
license=(GPL)
depends=('glib2' 'xz' 'zlib' 'libsoup' 'gpgme' 'libarchive' 'fuse2' 'util-linux' 'openssl' 'avahi')
makedepends=('e2fsprogs' 'gobject-introspection' 'gtk-doc' 'libxslt' 'systemd' 'git' 'python')
checkdepends=('parallel' 'syslinux' 'gjs' 'cpio' 'elfutils')
provides=('ostree')
conflicts=('ostree')
source=("git+https://github.com/ostreedev/ostree"
"git+https://github.com/mendsley/bsdiff"
"git+https://gitlab.gnome.org/GNOME/libglnx.git")
sha512sums=('SKIP'
'SKIP'
'SKIP')
prepare() {
cd $_pkgname
git submodule init
git config --local submodule.bsdiff.url "$srcdir/bsdiff"
git config --local submodule.libglnx.url "$srcdir/libglnx"
git submodule update
NOCONFIGURE=1 ./autogen.sh
}
pkgver() {
cd $_pkgname
git describe | sed 's/^v//;s/-/+/g'
}
build() {
cd $_pkgname
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--sbindir=/usr/bin \
--libexecdir=/usr/lib \
--with-mkinitcpio \
--with-openssl \
--with-builtin-grub2-mkconfig \
--enable-experimental-api \
--disable-static \
--enable-gtk-doc
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $_pkgname
make check || :
}
package() {
cd $_pkgname
make DESTDIR="$pkgdir" install
}
|