PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: MingxuanGame <MingxuanGame@outlook.com>

pkgname=osu-gu
pkgver=2026.713.0
pkgrel=1
pkgdesc="A free-to-win rhythm game. GooGuTeam fork of osu!lazer."
arch=(x86_64)
url="https://github.com/GooGuTeam/osu"
license=("MIT" "custom:CC-BY-NC 4.0")
makedepends=(dotnet-sdk)
depends=(
  zlib
  libgl
  dotnet-runtime-8.0
  osu-mime
)
provides=(osu-gu)
conflicts=(osu-gu-bin osu-gu-git)
options=(!strip !debug)
source=(
  "osu-${pkgver}-lazer.tar.gz::https://github.com/GooGuTeam/osu/archive/refs/tags/v${pkgver}-lazer.tar.gz"
  "icon.png"
  "https://raw.githubusercontent.com/ppy/osu-resources/master/LICENCE.md"
  "osu-gu.desktop"
  "osu-gu-uri-handler.desktop"
  "osu-gu"
)
sha256sums=('905a4330e5352e2f2de51083c4042642dfcc8215734f70d5cc8202dfee1048c7'
            '30cf4df3fd76006b08a0bcb6a325fb2fdcf6a4371f77001da3c38cbce871bd51'
            '30b914824784b6ba6b30a44b22bea4f3c6fbc10f3f0e74fde5ca76a92ef57244'
            '719733029ec5eddd3bfd9c7fdfcdcb5b4fbbc52a021d284448443d165191e34c'
            '9568f8057ace9236017f2b1a5e2df023f429915f11b99cfb26c936dce39ec63c'
            'caf1bb0929f1467d77cd4d3d94f28ebbdd4ce8b084f2193046fb40737a8bcc5b')

build() {
  cd "$srcdir/osu-${pkgver}-lazer"
  DOTNET_CLI_TELEMETRY_OPTOUT="1" dotnet publish osu.Desktop \
    --framework net8.0 \
    --configuration Release \
    --use-current-runtime \
    --no-self-contained \
    --output output \
    /property:Version="$pkgver"
}

package() {
  cd "$srcdir/osu-${pkgver}-lazer"
  install -d "$pkgdir/opt/osu-gu"
  cp -r output/* "$pkgdir/opt/osu-gu"
  install -Dm755 -t "$pkgdir/usr/bin" "$srcdir/osu-gu"
  install -Dm644 -t "$pkgdir/usr/share/applications" "$srcdir/osu-gu.desktop"
  install -Dm644 -t "$pkgdir/usr/share/applications" "$srcdir/osu-gu-uri-handler.desktop"
  install -Dm644 "$srcdir/icon.png" "$pkgdir/usr/share/pixmaps/osu-gu.png"
  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$srcdir/LICENCE.md"

  # Fix Vulkan renderer. See: https://github.com/ppy/osu/discussions/27659#discussioncomment-9101487
  ln -sf /usr/lib/libdl.so.2 "$pkgdir/opt/osu-gu/libdl.so"
}