blob: 2e2ccace4779be4e2f9ffa461eb9141d8ddbe3d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Maintainer: Ammon Smith <ammon.i.smith@gmail.com>
# Contributor: Nicole Fontenot <nfontenot27@gmail.com>
pkgname=osu-lazer-git
pkgver=2017.1116.0
pkgrel=1
pkgdesc='Freeware rhythm video game - lazer development version'
arch=('x86_64' 'i686')
url='https://osu.ppy.sh'
license=('MIT')
makedepends=('nuget4'
'msbuild-stable'
'git')
depends=('ffmpeg'
'libgl'
'mono')
optdepends=()
options=()
provides=('osu-lazer')
conflicts=('osu-lazer')
source=('git+https://github.com/ppy/osu.git'
'osu-launcher'
'osu-lazer.desktop'
'osu-lazer.png'
'x-osu-lazer.xml'
'NuGet.config')
sha256sums=('SKIP'
'c499dbff1d9a8f382e7b3cf4a95b58b9f02fb98e66e50cddb5d7d6c8a5223d2d'
'11d29c2654896607f37bc5c8e558ea245d8e3b1b412dcba03033bf1db6580ebe'
'3b3a9075f79ca7f2a4fd34eb182a5c1ada6eb118a95e49c1526df516365bbfe5'
'd22f0d922856639c7cc5f71bdd620cc8b3eb54af923b1a43703faac217b8b13b'
'171dc778d3f4408856b5b5bb9bffc272c7c9bd14cf0b11fd4026ccd57a2c4038')
case "$CARCH" in
x86_64)
_arch=x64
;;
i686)
_arch=x86
;;
esac
pkgver() {
cd "$srcdir/osu"
git describe --always --tags | sed 's/-/_/g' | cut -c 2-
}
build() {
cd "$srcdir/osu"
# Initialize submodules
git submodule init
git submodule update --recursive
# Download dependencies
nuget restore
nuget restore -configfile "$srcdir/NuGet.config"
# Build
msbuild /property:Configuration=Release
}
package() {
# Wrapper script
cd "$srcdir"
mkdir -p "$pkgdir/usr/bin"
install -m755 'osu-launcher' "$pkgdir/usr/bin/osu-lazer"
# MIME types
mkdir -p "$pkgdir/usr/share/mime/packages"
install -m644 "x-${pkgname%-git}.xml" "$pkgdir/usr/share/mime/packages/x-${pkgname%-git}.xml"
# Add .desktop file
mkdir -p "$pkgdir/usr/share/applications"
install -m644 "${pkgname%-git}.desktop" "$pkgdir/usr/share/applications/${pkgname%-git}.desktop"
# Application icon
mkdir -p "$pkgdir/usr/share/pixmaps"
install -m644 "${pkgname%-git}.png" "$pkgdir/usr/share/pixmaps/${pkgname%-git}.png"
# Compiled binaries
cd "$srcdir/osu/osu.Desktop/bin/Release"
mkdir -p "$pkgdir/usr/lib/${pkgname%-git}"
for binary in *.exe *.dll; do
install -m755 "$binary" "$pkgdir/usr/lib/${pkgname%-git}/$binary"
done
# Native libraries
install -m755 "libbass.$_arch.so" "$pkgdir/usr/lib/${pkgname%-git}/libbass.so"
install -m755 "libbass_fx.$_arch.so" "$pkgdir/usr/lib/${pkgname%-git}/libbass_fx.so"
}
# vim: set sw=4 ts=4 noet:
|