summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c21fefed176af132f9b691463a154e639fbf246c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Anton Bazhenov <anton.bazhenov at gmail>
# Contributor: cs-cam <me.at.camdaniel.com>

_commit=cc7f1b5a1220b3a3ffe356e056e6627c64bdf122
pkgname=otf2bdf
pkgver=3.1
pkgrel=3
pkgdesc="A command-line OpenType to BDF font converter"
arch=('i686' 'x86_64')
url="https://github.com/jirutka/otf2bdf/"
license=('custom')
depends=('freetype2')
source=("https://github.com/jirutka/otf2bdf/archive/$_commit/$pkgname-$pkgver.tar.gz")
sha256sums=('6f33ae2734ae48258201ce967a0b23cd88e901348591ee978e8250986781bcb4')

prepare() {
  cd "${srcdir}/${pkgname}-${_commit}"
  sed -r 's/freetype-config (--[a-z]+)/pkg-config \1 freetype2/' -i configure
}

build() {
  cd "${srcdir}/${pkgname}-${_commit}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${_commit}"
  install -Dm755 ${pkgname} "${pkgdir}/usr/bin/${pkgname}"

  # Install man page and license
  sed -n "1,21p" README > COPYING
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  install -Dm644 ${pkgname}.man "${pkgdir}/usr/share/man/man1/${pkgname}.1"
}