blob: 668c3d635203d3b1bf468f8cd69e14e575316956 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- sh -*-
_pkgname='ov'
pkgname="${_pkgname}-git"
pkgver=0.33.3.r2.g8c70587
pkgrel=2
epoch=1
pkgdesc='Feature-rich terminal-based text pager (built from latest commit)'
arch=('aarch64' 'arm' 'armv6h' 'armv7h' 'i686' 'x86_64')
url='https://github.com/noborus/ov'
license=('MIT') # SPDX-License-Identifier: MIT
provides=('ov')
conflicts=('ov')
depends=('glibc')
makedepends=('git' 'go')
source=("git+$url.git")
options=('lto')
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/^v//;s/-rc\d*//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_pkgname"
mkdir -p build
go mod tidy
}
build() {
cd "$_pkgname"
_ver=$(git describe --tags --abbrev=0 --always | sed 's/^v//g')
_rev=$(git rev-parse --verify --short HEAD)
# RFC-0023
# 🔗 https://rfc.archlinux.page/0023-pack-relative-relocs/
#
# ld(1) says: “Supported for i386 and x86-64.”
case "${CARCH:-unknown}" in
'x86_64' | 'i386' )
export LDFLAGS="$LDFLAGS -Wl,-z,pack-relative-relocs"
;;
* ) : pass ;;
esac
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
go build \
-buildmode=pie \
-trimpath \
-ldflags="-linkmode=external -X main.Version=$_ver -X main.Revision=$_rev" \
-mod=readonly -modcacherw \
-o build
}
check() {
cd "$_pkgname"
go test
}
package() {
cd "$_pkgname"
install -vDm0755 "build/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
install -vDm0644 -t "$pkgdir/usr/share/doc/$pkgname/" *.yaml README.md
install -vDm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
for _shell in bash fish zsh; do
"$pkgdir/usr/bin/$_pkgname" --completion "$_shell" > "completion.$_shell"
done
install -vDm0644 completion.bash \
"$pkgdir/usr/share/bash-completion/completions/$_pkgname"
install -vDm0644 completion.fish \
"$pkgdir/usr/share/fish/vendor_completions.d/$_pkgname.fish"
install -vDm0644 completion.zsh \
"$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
}
# eof
|